Esp8266 Nodemcu Relay Control from Web page over WiFi.

Esp8266 Nodemcu Relay Control from  Web page over WiFi.
Today I like to show you how you can use the Esp8266 Nodemcu  and a 4 channel relay module to create a webserver that enables us to control devices from a web page over a WiFi network. This acts as a switch in a number of home automation projects.
Before we can proceed you should look at my other posts on how to use the 4 channel relay module and how to create a web server using the nodemcu;
  • Interfacing 5V 4-Channel Relay Module with Arduino
  • Nodemcu Webserver with Arduino IDE for Controlling Leds.
  • Connections for the Esp8266 Nodemcu with the 5V 4 channel relay module.

    schematic
    One of the challenges you may find will be power supply to the relay and esp8266 Nodemcu since these devices use different voltages. In the schematic above we have supplied the Nodemcu with a USB power supply from a computer and the relay uses a different 5V power supply.
    In the above schematic I have used Leds to demonstrate how the various devices can be connected to the relay module. However if you are to connect high voltage home appliances like bulbs, fans and others, you need to be very careful when handling high voltage sources!

    CODE

        #include <ESP8266WiFi.h>
    // Replace with your network credentials
    const char* ssid = "WiFi name"; // Input your wifi network name
    const char* password = "WiFi password"; // Input your wifi password
    
    // Set web server port number to 80
    WiFiServer server(80);
    
    // Variable to store the HTTP request
    String header;
    
    // Auxiliar variables to store the current output state
    String relay1State = "off";
    String relay2State = "off";
    String relay3State = "off";
    String relay4State = "off";
    
    // Assign output variables to GPIO pins
    const int relay1 = 5; // GPIO5 D1
    const int relay2 = 4; // GPIO4 D2
    const int relay3 = 0; // GPIO0 D3
    const int relay4 = 2; // GPIO2 D4
    
    void setup() {
      Serial.begin(115200);
      // Initialize the output variables as outputs
      pinMode(relay1, OUTPUT);
      pinMode(relay2, OUTPUT);
      pinMode(relay3, OUTPUT);
      pinMode(relay4, OUTPUT);
      // Set outputs to HIGH. relay active LOW
      digitalWrite(relay1, HIGH);
      digitalWrite(relay2, HIGH);
      digitalWrite(relay3, HIGH);
      digitalWrite(relay4, HIGH);
    
      // Connect to Wi-Fi network with SSID and password
      Serial.print("Connecting to ");
      Serial.println(ssid);
      WiFi.begin(ssid, password);
      while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
      }
      // Print local IP address and start web server
      Serial.println("");
      Serial.println("WiFi connected.");
      Serial.println("IP address: ");
      Serial.println(WiFi.localIP());
      server.begin();
    }
    
    void loop() {
      WiFiClient client = server.available();   // Listen for incoming clients
    
      if (client) {                             // If a new client connects,
        Serial.println("New Client.");          // print a message out in the serial port
        String currentLine = "";                // make a String to hold incoming data from the client
        while (client.connected()) {            // loop while the client's connected
          if (client.available()) {             // if there's bytes to read from the client,
            char c = client.read();             // read a byte, then
            Serial.write(c);                    // print it out the serial monitor
            header += c;
            if (c == '\n') {                    // if the byte is a newline character
              // if the current line is blank, you got two newline characters in a row.
              // that's the end of the client HTTP request, so send a response:
              if (currentLine.length() == 0) {
                // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
                // and a content-type so the client knows what's coming, then a blank line:
                client.println("HTTP/1.1 200 OK");
                client.println("Content-type:text/html");
                client.println("Connection: close");
                client.println();
    
                // turns the GPIOs on and off
                if (header.indexOf("GET /5/on") >= 0)
                {
                  Serial.println("GPIO 5 on");
                  relay1State = "on";
                  digitalWrite(relay1, LOW);
                }
                else if (header.indexOf("GET /5/off") >= 0)
                {
                  Serial.println("GPIO 5 off");
                  relay1State = "off";
                  digitalWrite(relay1, HIGH);
                }
                else if (header.indexOf("GET /4/on") >= 0) {
                  Serial.println("GPIO 4 on");
                  relay2State = "on";
                  digitalWrite(relay2, LOW);
                }
                else if (header.indexOf("GET /4/off") >= 0) {
                  Serial.println("GPIO 4 off");
                  relay2State = "off";
                  digitalWrite(relay2, HIGH);
                }
                else if (header.indexOf("GET /0/on") >= 0)
                {
                  Serial.println("GPIO 0 on");
                  relay3State = "on";
                  digitalWrite(relay3, LOW);
                }
                else if (header.indexOf("GET /0/off") >= 0)
                {
                  Serial.println("GPIO 0 off");
                  relay3State = "off";
                  digitalWrite(relay3, HIGH);
                }
                else if (header.indexOf("GET /2/on") >= 0) {
                  Serial.println("GPIO 2 on");
                  relay4State = "on";
                  digitalWrite(relay4, LOW);
                }
                else if (header.indexOf("GET /2/off") >= 0) {
                  Serial.println("GPIO 2 off");
                  relay4State = "off";
                  digitalWrite(relay4, HIGH);
                }
    
                // Display the HTML web page
                client.println("<!DOCTYPE html><html>");
                client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
                //client.println("<link rel=\"icon\" href=\"data:,\">");
                // CSS to style the on/off buttons
                // Feel free to change the background-color and font-size attributes to fit your preferences
                client.println("<style>html, body { font-family: Helvetica; display: block; margin: 0px auto; text-align: center;}");
                client.println(".button { background-color: #209e48; border: none; color: white; padding: 12px 24px;");
                client.println("text-decoration: none; font-size: 20px; margin: 2px; cursor: pointer;}");
                client.println(".button2 {background-color: #c20a0a;}");
                client.println(".textbox {width: 80px; border: 1px solid #333; padding: 16px 20px 0px 24px; background-image: linear-gradient(180deg, #fff, #ddd 40%, #ccc);}");
                client.println(".mytext {font-size: 16px; font-weight:bold; font-family:Arial ; text-align: justify;}");
                client.println("#container {width: 100%; height: 100%; margin-left: 5px; margin-top: 20px; padding: 10px; display: -webkit-flex; -webkit-justify-content: center; display: flex; justify-content: center;} ");
                
                client.println("</style></head>");
    
                
                // Web Page Heading
                client.println("<body><h1>NodeMCU Web Server Relay Control</h1>");
    
                // Display current state, and ON/OFF buttons for GPIO 5
                client.println("<div id=\"container\">");
                client.println("<p><div class=\"textbox mytext\">RELAY 1 </div> ");
                // If the relay1State is off, it displays the ON button
                if (relay1State == "off") {
                  client.println("<a href=\"/5/on\"><button class=\"button\">OFF</button></a></p>");
                } else {
                  client.println("<a href=\"/5/off\"><button class=\"button button2\">ON</button></a></p>");
                }
                client.println("</div>");
                
                // Display current state, and ON/OFF buttons for GPIO 4
                client.println("<div id=\"container\">");
                client.println("<p><div class=\"textbox mytext\">RELAY 2 </div> ");
                // If the relay2State is off, it displays the ON button
                if (relay2State == "off") {
                  client.println("<a href=\"/4/on\"><button class=\"button\">OFF</button></a></p>");
                } else {
                  client.println("<a href=\"/4/off\"><button class=\"button button2\">ON</button></a></p>");
                }
                client.println("</div>");
    
                // Display current state, and ON/OFF buttons for GPIO 0
                client.println("<div id=\"container\">");
                client.println("<p><div class=\"textbox mytext\">RELAY 3 </div>");
                // If the relay1State is off, it displays the ON button
                if (relay3State == "off") {
                  client.println("<a href=\"/0/on\"><button class=\"button\">OFF</button></a></p>");
                } else {
                  client.println("<a href=\"/0/off\"><button class=\"button button2\">ON</button></a></p>");
                }
                client.println("</div>");
                
                // Display current state, and ON/OFF buttons for GPIO 2
                client.println("<div id=\"container\">");
                client.println("<p><div class=\"textbox mytext\">RELAY 4 </div>");
                // If the relay2State is off, it displays the ON button
                if (relay4State == "off") {
                  client.println("<a href=\"/2/on\"><button class=\"button\">OFF</button></a></p>");
                } else {
                  client.println("<a href=\"/2/off\"><button class=\"button button2\">ON</button></a></p>");
                }
                client.println("</div>");
    
                client.println("</body></html>");
    
                // The HTTP response ends with another blank line
                client.println();
                // Break out of the while loop
                break;
              } else { // if you got a newline, then clear currentLine
                currentLine = "";
              }
            } else if (c != '\r') {  // if you got anything else but a carriage return character,
              currentLine += c;      // add it to the end of the currentLine
            }
          }
        }
        // Clear the header variable
        header = "";
        // Close the connection
        client.stop();
        Serial.println("Client disconnected.");
        Serial.println("");
      }
    }
    
    
    When the code is uploaded to the Nodemcu, we can be able to see the url from the serial monitor and using this URL we can be able to access the control web page from any device like a mobile phone or laptop. The web page for Esp8266 nodemcu relay control will look like shown here. The design of this page can be changed in the code but only do so if you have prior knowledge of web development and design.
    From this webpage we can turn the relays on and off. When a specific relay is off the button will be green and when pressed it turns to red showing that the relay is on.
    nodemcu relay control web page
    Back to top